Skip to content

Simple Messages

DiSky allows you to send or reply to messages. Although simple text works, bots can also use "embeds", with different ways to organize the structure of your message.

Simple Text Message

Simple text messages are just ... text! Use the post effect (or reply if you're in a DiSky event) and just specify the text you can send:

reply with "Oh, hello there!"
post "Hello World!" to text channel with id "000" # specific channel

Image title

Result of a response in a slash command

Simple Embed Message

An embed can have different properties:

  • Title (+ title URL)
  • Author (+ author icon & URL)
  • Description
  • Color
  • Image
  • Thumbnail
  • Footer (+ footer icon)
  • Timestamp
  • Fields (inline or not)

Here's an example embed containing all the above properties:

Image title

Full example of an embed


You cannot set a "sub" property (in orange) without setting the main property. For example, you can't set an author icon without an author.

The code for the above embed is the following:

make embed and store it in {_embed}: #(1)!
    set title of embed to "Title"
    set title url of embed to ""

    set description of embed to "Description%nl%The title leads to the URL, if given"

    set author of the embed to "Author name (Can point to URL)" # author must be set first
    set author icon of embed to ""
    set author url of embed to ""

    set embed color of the embed to orange #(2)!

    add inline field named "Field Name" with value "Colour sets %nl%< that" to fields of embed
    add inline field named "Field Name" with value "Color is a java Color%nl%Not a string" to fields of embed
    add inline field named "Field Name" with value "Field value" to fields of embed
    add field named "Non-inline field name" with value "The number of fields that can be shown on the same row is limited to 3, but is limited to 2 when an image is included" to fields of embed

    set footer of embed to "Footer text"
    set footer icon of embed to ""

    set image of embed to ""
    set thumbnail of embed to ""
    set timestamp of embed to now
  1. The provided variable will be changed along with the embed, but the embed expression is only available in the make embed section!
  2. You can also use a color from its hex code using set embed color of embed to hex "#FF0000"!

Once the section is run, you can post/reply with the newly stored embed, such as:

make embed:
reply with {_embed}
make embed:
post {_embed} to text channel with id "000"